| 1 |
##################################################################### |
| 2 |
# Qt documentation build |
| 3 |
##################################################################### |
| 4 |
|
| 5 |
win32 { |
| 6 |
QT_WINCONFIG = release/ |
| 7 |
!CONFIG(release, debug|release) { |
| 8 |
QT_WINCONFIG = debug/ |
| 9 |
} |
| 10 |
} |
| 11 |
|
| 12 |
DOCS_GENERATION_DEFINES = -Dopensourceedition |
| 13 |
GENERATOR = $$QT_BUILD_TREE/bin/qhelpgenerator |
| 14 |
|
| 15 |
win32:!win32-g++ { |
| 16 |
unixstyle = false |
| 17 |
} else :win32-g++:isEmpty(QMAKE_SH) { |
| 18 |
unixstyle = false |
| 19 |
} else { |
| 20 |
unixstyle = true |
| 21 |
} |
| 22 |
|
| 23 |
$$unixstyle { |
| 24 |
QDOC = cd $$QT_SOURCE_TREE/tools/qdoc3/test && QT_BUILD_TREE=$$QT_BUILD_TREE QT_SOURCE_TREE=$$QT_SOURCE_TREE $$QT_BUILD_TREE/tools/qdoc3/$${QT_WINCONFIG}qdoc3 $$DOCS_GENERATION_DEFINES |
| 25 |
} else { |
| 26 |
QDOC = cd $$QT_SOURCE_TREE/tools/qdoc3/test && set QT_BUILD_TREE=$$QT_BUILD_TREE&& set QT_SOURCE_TREE=$$QT_SOURCE_TREE&& $$QT_BUILD_TREE/tools/qdoc3/$${QT_WINCONFIG}qdoc3.exe $$DOCS_GENERATION_DEFINES |
| 27 |
QDOC = $$replace(QDOC, "/", "\\") |
| 28 |
} |
| 29 |
macx { |
| 30 |
ADP_DOCS_QDOCCONF_FILE = qt-build-docs-with-xcode.qdocconf |
| 31 |
} else { |
| 32 |
ADP_DOCS_QDOCCONF_FILE = qt-build-docs.qdocconf |
| 33 |
} |
| 34 |
QT_DOCUMENTATION = ($$QDOC qt-api-only.qdocconf assistant.qdocconf designer.qdocconf \ |
| 35 |
linguist.qdocconf qmake.qdocconf) && \ |
| 36 |
(cd $$QT_BUILD_TREE && \ |
| 37 |
$$GENERATOR doc-build/html-qt/qt.qhp -o doc/qch/qt.qch && \ |
| 38 |
$$GENERATOR doc-build/html-assistant/assistant.qhp -o doc/qch/assistant.qch && \ |
| 39 |
$$GENERATOR doc-build/html-designer/designer.qhp -o doc/qch/designer.qch && \ |
| 40 |
$$GENERATOR doc-build/html-linguist/linguist.qhp -o doc/qch/linguist.qch && \ |
| 41 |
$$GENERATOR doc-build/html-qmake/qmake.qhp -o doc/qch/qmake.qch \ |
| 42 |
) |
| 43 |
|
| 44 |
win32-g++:isEmpty(QMAKE_SH) { |
| 45 |
QT_DOCUMENTATION = $$replace(QT_DOCUMENTATION, "/", "\\\\") |
| 46 |
} |
| 47 |
|
| 48 |
|
| 49 |
!wince*:!cross_compile:SUBDIRS += tools/qdoc3 |
| 50 |
|
| 51 |
# Build rules: |
| 52 |
adp_docs.commands = ($$QDOC $$ADP_DOCS_QDOCCONF_FILE) |
| 53 |
adp_docs.depends += sub-tools-qdoc3 |
| 54 |
qch_docs.commands = $$QT_DOCUMENTATION |
| 55 |
qch_docs.depends += sub-tools |
| 56 |
|
| 57 |
docs.depends = adp_docs qch_docs |
| 58 |
|
| 59 |
# Install rules |
| 60 |
htmldocs.files = $$QT_BUILD_TREE/doc/html |
| 61 |
htmldocs.path = $$[QT_INSTALL_DOCS] |
| 62 |
htmldocs.CONFIG += no_check_exist |
| 63 |
|
| 64 |
qchdocs.files= $$QT_BUILD_TREE/doc/qch |
| 65 |
qchdocs.path = $$[QT_INSTALL_DOCS] |
| 66 |
qchdocs.CONFIG += no_check_exist |
| 67 |
|
| 68 |
docimages.files = $$QT_BUILD_TREE/doc/src/images |
| 69 |
docimages.path = $$[QT_INSTALL_DOCS]/src |
| 70 |
|
| 71 |
QMAKE_EXTRA_TARGETS += qdoc adp_docs qch_docs docs |
| 72 |
INSTALLS += htmldocs qchdocs docimages |
