projects.pro - qt in Qt

#####################################################################
# Main projectfile
#####################################################################

CONFIG += ordered
TEMPLATE = subdirs

cross_compile: CONFIG += nostrip

isEmpty(QT_BUILD_PARTS) { #defaults
    symbian {
       QT_BUILD_PARTS = libs tools examples demos
    } else {
       QT_BUILD_PARTS = libs tools examples demos docs translations
    }
} else { #make sure the order makes sense
   contains(QT_BUILD_PARTS, translations) {
       QT_BUILD_PARTS -= translations
       QT_BUILD_PARTS = translations $$QT_BUILD_PARTS
   }
   contains(QT_BUILD_PARTS, tools) {
       QT_BUILD_PARTS -= tools
       QT_BUILD_PARTS = tools $$QT_BUILD_PARTS
   }
   contains(QT_BUILD_PARTS, libs) {
       QT_BUILD_PARTS -= libs
       QT_BUILD_PARTS = libs $$QT_BUILD_PARTS
   }
   contains(QT_BUILD_PARTS, qmake) {
       QT_BUILD_PARTS -= qmake
       QT_BUILD_PARTS = qmake $$QT_BUILD_PARTS
   }
}

#process the projects
for(PROJECT, $$list($$lower($$unique(QT_BUILD_PARTS)))) {
    isEqual(PROJECT, tools) {
       SUBDIRS += tools
    } else:isEqual(PROJECT, examples) {
       SUBDIRS += examples
    } else:isEqual(PROJECT, demos) {
       SUBDIRS += demos
    } else:isEqual(PROJECT, libs) {
       include(src/src.pro)
    } else:isEqual(PROJECT, docs) {
       contains(QT_BUILD_PARTS, tools):include(doc/doc.pri)
    } else:isEqual(PROJECT, translations) {
       contains(QT_BUILD_PARTS, tools) {
          include(translations/translations.pri)  # ts targets
       } else {
          !wince*:!symbian:SUBDIRS += tools/linguist/lrelease
       }
       SUBDIRS += translations                    # qm build step
    } else:isEqual(PROJECT, qmake) {
#      SUBDIRS += qmake
    } else {
       message(Unknown PROJECT: $$PROJECT)
    }
}

!symbian: confclean.depends += clean
confclean.commands =
unix:!symbian {
  confclean.commands += (cd config.tests/unix/stl && $(MAKE) distclean); \
			(cd config.tests/unix/endian && $(MAKE) distclean); \
			(cd config.tests/unix/ipv6 && $(MAKE) distclean); \
			(cd config.tests/unix/largefile && $(MAKE) distclean); \
			(cd config.tests/unix/ptrsize && $(MAKE) distclean); \
			(cd config.tests/x11/notype && $(MAKE) distclean); \
			(cd config.tests/unix/getaddrinfo && $(MAKE) distclean); \
			(cd config.tests/unix/cups && $(MAKE) distclean); \
			(cd config.tests/unix/psql && $(MAKE) distclean); \
			(cd config.tests/unix/mysql && $(MAKE) distclean); \
 	 		(cd config.tests/unix/mysql_r && $(MAKE) distclean); \
			(cd config.tests/unix/nis && $(MAKE) distclean); \
			(cd config.tests/unix/nix && $(MAKE) distclean); \
			(cd config.tests/unix/iodbc && $(MAKE) distclean); \
			(cd config.tests/unix/odbc && $(MAKE) distclean); \
			(cd config.tests/unix/oci && $(MAKE) distclean); \
			(cd config.tests/unix/tds && $(MAKE) distclean); \
			(cd config.tests/unix/db2 && $(MAKE) distclean); \
			(cd config.tests/unix/ibase && $(MAKE) distclean); \
			(cd config.tests/unix/ipv6ifname && $(MAKE) distclean); \
			(cd config.tests/unix/zlib && $(MAKE) distclean); \
			(cd config.tests/unix/libmng && $(MAKE) distclean); \
			(cd config.tests/unix/sqlite2 && $(MAKE) distclean); \
			(cd config.tests/unix/libjpeg && $(MAKE) distclean); \
			(cd config.tests/unix/libpng && $(MAKE) distclean); \
			(cd config.tests/x11/xcursor && $(MAKE) distclean); \
			(cd config.tests/x11/xrender && $(MAKE) distclean); \
			(cd config.tests/x11/xrandr && $(MAKE) distclean); \
			(cd config.tests/x11/xkb && $(MAKE) distclean); \
			(cd config.tests/x11/xinput && $(MAKE) distclean); \
			(cd config.tests/x11/fontconfig && $(MAKE) distclean); \
			(cd config.tests/x11/xinerama && $(MAKE) distclean); \
			(cd config.tests/x11/sm && $(MAKE) distclean); \
			(cd config.tests/x11/xshape && $(MAKE) distclean); \
			(cd config.tests/x11/opengl && $(MAKE) distclean); \
                        $(DEL_FILE) config.tests/.qmake.cache; \
			$(DEL_FILE) src/core/global/qconfig.h; \
			$(DEL_FILE) src/core/global/qconfig.cpp; \
			$(DEL_FILE) mkspecs/qconfig.pri; \
			$(DEL_FILE) .qmake.cache; \
 			(cd qmake && $(MAKE) distclean);
}
win32 {
  confclean.commands += -$(DEL_FILE) src\core\global\qconfig.h $$escape_expand(\n\t) \
			-$(DEL_FILE) src\core\global\qconfig.cpp $$escape_expand(\n\t) \
			-$(DEL_FILE) mkspecs\qconfig.pri $$escape_expand(\n\t) \
			-$(DEL_FILE) .qmake.cache $$escape_expand(\n\t) \
			(cd qmake && $(MAKE) distclean)
}
symbian {
  confclean.depends += distclean
  contains(QMAKE_HOST.os, "Windows") {
    confclean.commands += \
            (cd src\tools\moc && $(MAKE) distclean) $$escape_expand(\n\t) \
            (cd src\tools\rcc && $(MAKE) distclean) $$escape_expand(\n\t) \
            (cd src\tools\uic && $(MAKE) distclean) $$escape_expand(\n\t) \
            -$(DEL_FILE) src\corelib\global\qconfig.h $$escape_expand(\n\t) \
            -$(DEL_FILE) src\corelib\global\qconfig.cpp $$escape_expand(\n\t) \
            -$(DEL_FILE) mkspecs\qconfig.pri $$escape_expand(\n\t) \
            -$(DEL_FILE) .qmake.cache $$escape_expand(\n\t) \
            (cd qmake && $(MAKE) distclean)
  } else {
    confclean.commands += \
            (cd src/tools/moc && $(MAKE) distclean) $$escape_expand(\n\t) \
            (cd src/tools/rcc && $(MAKE) distclean) $$escape_expand(\n\t) \
            (cd src/tools/uic && $(MAKE) distclean) $$escape_expand(\n\t) \
            -$(DEL_FILE) src/corelib/global/qconfig.h $$escape_expand(\n\t) \
            -$(DEL_FILE) src/corelib/global/qconfig.cpp $$escape_expand(\n\t) \
            -$(DEL_FILE) mkspecs/qconfig.pri $$escape_expand(\n\t) \
            -$(DEL_FILE) .qmake.cache $$escape_expand(\n\t) \
            (cd qmake && $(MAKE) distclean)
  }
}
QMAKE_EXTRA_TARGETS += confclean
qmakeclean.commands += (cd qmake && $(MAKE) clean)
QMAKE_EXTRA_TARGETS += qmakeclean
CLEAN_DEPS += qmakeclean

CONFIG -= qt

### installations ####

#translations
translations.path=$$[QT_INSTALL_TRANSLATIONS]
translations.files = $$QT_SOURCE_TREE/translations/*.qm
INSTALLS += translations

#qmake
qmake.path=$$[QT_INSTALL_BINS]
win32 {
   qmake.files=$$QT_BUILD_TREE/bin/qmake.exe
} else {
   qmake.files=$$QT_BUILD_TREE/bin/qmake
}
INSTALLS += qmake

#mkspecs
mkspecs.path=$$[QT_INSTALL_DATA]/mkspecs
mkspecs.files=$$QT_BUILD_TREE/mkspecs/qconfig.pri $$QT_SOURCE_TREE/mkspecs/*
unix { 
   DEFAULT_QMAKESPEC = $$QMAKESPEC
   DEFAULT_QMAKESPEC ~= s,^.*mkspecs/,,g
   mkspecs.commands += $(DEL_FILE) $(INSTALL_ROOT)$$mkspecs.path/default; $(SYMLINK) $$DEFAULT_QMAKESPEC $(INSTALL_ROOT)$$mkspecs.path/default
}
INSTALLS += mkspecs

false:macx { #mac install location
    macdocs.files = $$htmldocs.files
    macdocs.path = /Developer/Documentation/Qt
    INSTALLS += macdocs
}

1	#####################################################################
2	# Main projectfile
3	#####################################################################
4
5	CONFIG += ordered
6	TEMPLATE = subdirs
7
8	cross_compile: CONFIG += nostrip
9
10	isEmpty(QT_BUILD_PARTS) { #defaults
11	symbian {
12	QT_BUILD_PARTS = libs tools examples demos
13	} else {
14	QT_BUILD_PARTS = libs tools examples demos docs translations
15	}
16	} else { #make sure the order makes sense
17	contains(QT_BUILD_PARTS, translations) {
18	QT_BUILD_PARTS -= translations
19	QT_BUILD_PARTS = translations $$QT_BUILD_PARTS
20	}
21	contains(QT_BUILD_PARTS, tools) {
22	QT_BUILD_PARTS -= tools
23	QT_BUILD_PARTS = tools $$QT_BUILD_PARTS
24	}
25	contains(QT_BUILD_PARTS, libs) {
26	QT_BUILD_PARTS -= libs
27	QT_BUILD_PARTS = libs $$QT_BUILD_PARTS
28	}
29	contains(QT_BUILD_PARTS, qmake) {
30	QT_BUILD_PARTS -= qmake
31	QT_BUILD_PARTS = qmake $$QT_BUILD_PARTS
32	}
33	}
34
35	#process the projects
36	for(PROJECT, $$list($$lower($$unique(QT_BUILD_PARTS)))) {
37	isEqual(PROJECT, tools) {
38	SUBDIRS += tools
39	} else:isEqual(PROJECT, examples) {
40	SUBDIRS += examples
41	} else:isEqual(PROJECT, demos) {
42	SUBDIRS += demos
43	} else:isEqual(PROJECT, libs) {
44	include(src/src.pro)
45	} else:isEqual(PROJECT, docs) {
46	contains(QT_BUILD_PARTS, tools):include(doc/doc.pri)
47	} else:isEqual(PROJECT, translations) {
48	contains(QT_BUILD_PARTS, tools) {
49	include(translations/translations.pri) # ts targets
50	} else {
51	!wince*:!symbian:SUBDIRS += tools/linguist/lrelease
52	}
53	SUBDIRS += translations # qm build step
54	} else:isEqual(PROJECT, qmake) {
55	# SUBDIRS += qmake
56	} else {
57	message(Unknown PROJECT: $$PROJECT)
58	}
59	}
60
61	!symbian: confclean.depends += clean
62	confclean.commands =
63	unix:!symbian {
64	confclean.commands += (cd config.tests/unix/stl && $(MAKE) distclean); \
65	(cd config.tests/unix/endian && $(MAKE) distclean); \
66	(cd config.tests/unix/ipv6 && $(MAKE) distclean); \
67	(cd config.tests/unix/largefile && $(MAKE) distclean); \
68	(cd config.tests/unix/ptrsize && $(MAKE) distclean); \
69	(cd config.tests/x11/notype && $(MAKE) distclean); \
70	(cd config.tests/unix/getaddrinfo && $(MAKE) distclean); \
71	(cd config.tests/unix/cups && $(MAKE) distclean); \
72	(cd config.tests/unix/psql && $(MAKE) distclean); \
73	(cd config.tests/unix/mysql && $(MAKE) distclean); \
74	(cd config.tests/unix/mysql_r && $(MAKE) distclean); \
75	(cd config.tests/unix/nis && $(MAKE) distclean); \
76	(cd config.tests/unix/nix && $(MAKE) distclean); \
77	(cd config.tests/unix/iodbc && $(MAKE) distclean); \
78	(cd config.tests/unix/odbc && $(MAKE) distclean); \
79	(cd config.tests/unix/oci && $(MAKE) distclean); \
80	(cd config.tests/unix/tds && $(MAKE) distclean); \
81	(cd config.tests/unix/db2 && $(MAKE) distclean); \
82	(cd config.tests/unix/ibase && $(MAKE) distclean); \
83	(cd config.tests/unix/ipv6ifname && $(MAKE) distclean); \
84	(cd config.tests/unix/zlib && $(MAKE) distclean); \
85	(cd config.tests/unix/libmng && $(MAKE) distclean); \
86	(cd config.tests/unix/sqlite2 && $(MAKE) distclean); \
87	(cd config.tests/unix/libjpeg && $(MAKE) distclean); \
88	(cd config.tests/unix/libpng && $(MAKE) distclean); \
89	(cd config.tests/x11/xcursor && $(MAKE) distclean); \
90	(cd config.tests/x11/xrender && $(MAKE) distclean); \
91	(cd config.tests/x11/xrandr && $(MAKE) distclean); \
92	(cd config.tests/x11/xkb && $(MAKE) distclean); \
93	(cd config.tests/x11/xinput && $(MAKE) distclean); \
94	(cd config.tests/x11/fontconfig && $(MAKE) distclean); \
95	(cd config.tests/x11/xinerama && $(MAKE) distclean); \
96	(cd config.tests/x11/sm && $(MAKE) distclean); \
97	(cd config.tests/x11/xshape && $(MAKE) distclean); \
98	(cd config.tests/x11/opengl && $(MAKE) distclean); \
99	$(DEL_FILE) config.tests/.qmake.cache; \
100	$(DEL_FILE) src/core/global/qconfig.h; \
101	$(DEL_FILE) src/core/global/qconfig.cpp; \
102	$(DEL_FILE) mkspecs/qconfig.pri; \
103	$(DEL_FILE) .qmake.cache; \
104	(cd qmake && $(MAKE) distclean);
105	}
106	win32 {
107	confclean.commands += -$(DEL_FILE) src\core\global\qconfig.h $$escape_expand(\n\t) \
108	-$(DEL_FILE) src\core\global\qconfig.cpp $$escape_expand(\n\t) \
109	-$(DEL_FILE) mkspecs\qconfig.pri $$escape_expand(\n\t) \
110	-$(DEL_FILE) .qmake.cache $$escape_expand(\n\t) \
111	(cd qmake && $(MAKE) distclean)
112	}
113	symbian {
114	confclean.depends += distclean
115	contains(QMAKE_HOST.os, "Windows") {
116	confclean.commands += \
117	(cd src\tools\moc && $(MAKE) distclean) $$escape_expand(\n\t) \
118	(cd src\tools\rcc && $(MAKE) distclean) $$escape_expand(\n\t) \
119	(cd src\tools\uic && $(MAKE) distclean) $$escape_expand(\n\t) \
120	-$(DEL_FILE) src\corelib\global\qconfig.h $$escape_expand(\n\t) \
121	-$(DEL_FILE) src\corelib\global\qconfig.cpp $$escape_expand(\n\t) \
122	-$(DEL_FILE) mkspecs\qconfig.pri $$escape_expand(\n\t) \
123	-$(DEL_FILE) .qmake.cache $$escape_expand(\n\t) \
124	(cd qmake && $(MAKE) distclean)
125	} else {
126	confclean.commands += \
127	(cd src/tools/moc && $(MAKE) distclean) $$escape_expand(\n\t) \
128	(cd src/tools/rcc && $(MAKE) distclean) $$escape_expand(\n\t) \
129	(cd src/tools/uic && $(MAKE) distclean) $$escape_expand(\n\t) \
130	-$(DEL_FILE) src/corelib/global/qconfig.h $$escape_expand(\n\t) \
131	-$(DEL_FILE) src/corelib/global/qconfig.cpp $$escape_expand(\n\t) \
132	-$(DEL_FILE) mkspecs/qconfig.pri $$escape_expand(\n\t) \
133	-$(DEL_FILE) .qmake.cache $$escape_expand(\n\t) \
134	(cd qmake && $(MAKE) distclean)
135	}
136	}
137	QMAKE_EXTRA_TARGETS += confclean
138	qmakeclean.commands += (cd qmake && $(MAKE) clean)
139	QMAKE_EXTRA_TARGETS += qmakeclean
140	CLEAN_DEPS += qmakeclean
141
142	CONFIG -= qt
143
144	### installations ####
145
146	#translations
147	translations.path=$$[QT_INSTALL_TRANSLATIONS]
148	translations.files = $$QT_SOURCE_TREE/translations/*.qm
149	INSTALLS += translations
150
151	#qmake
152	qmake.path=$$[QT_INSTALL_BINS]
153	win32 {
154	qmake.files=$$QT_BUILD_TREE/bin/qmake.exe
155	} else {
156	qmake.files=$$QT_BUILD_TREE/bin/qmake
157	}
158	INSTALLS += qmake
159
160	#mkspecs
161	mkspecs.path=$$[QT_INSTALL_DATA]/mkspecs
162	mkspecs.files=$$QT_BUILD_TREE/mkspecs/qconfig.pri $$QT_SOURCE_TREE/mkspecs/*
163	unix {
164	DEFAULT_QMAKESPEC = $$QMAKESPEC
165	DEFAULT_QMAKESPEC ~= s,^.*mkspecs/,,g
166	mkspecs.commands += $(DEL_FILE) $(INSTALL_ROOT)$$mkspecs.path/default; $(SYMLINK) $$DEFAULT_QMAKESPEC $(INSTALL_ROOT)$$mkspecs.path/default
167	}
168	INSTALLS += mkspecs
169
170	false:macx { #mac install location
171	macdocs.files = $$htmldocs.files
172	macdocs.path = /Developer/Documentation/Qt
173	INSTALLS += macdocs
174	}

Gitorious