include(icecc.cmake) # this must be the first line!

project(pyside)

cmake_minimum_required(VERSION 2.6)

set(CMAKE_CXX_FLAGS_RELEASE "-Wall -fvisibility=hidden -fvisibility-inlines-hidden -Os -finline-limit=600 -ffunction-sections -fomit-frame-pointer -fno-default-inline -fconserve-space -fno-enforce-eh-specs -fno-threadsafe-statics -fno-implicit-inline-templates -DNDEBUG -DBOOST_PYTHON_NO_PY_SIGNATURES -Wno-strict-aliasing")

set(CMAKE_CXX_CFLAGS_DEBUG "-g -fno-common -Wall")

#OS Flags

if(CMAKE_HOST_UNIX)

    if(CMAKE_HOST_APPLE)

        if(NOT QT_INCLUDE_DIR)

            set(QT_INCLUDE_DIR "/Library/Frameworks")

        endif(NOT QT_INCLUDE_DIR)

    else(CMAKE_HOST_APPLE)

        set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -Wl,--gc-sections -Wl,-O1 -Wl,--hash-style=gnu")

    endif(CMAKE_HOST_APPLE)

endif(CMAKE_HOST_UNIX)

find_package(Boost 1.40.0 COMPONENTS python REQUIRED)

find_package(PythonLibs REQUIRED)

find_package(PythonInterp REQUIRED)

find_package(Qt4 4.5.0 REQUIRED)

set(BINDING_NAME PySide)

set(BINDING_API_MAJOR_VERSION "0")

set(BINDING_API_MINOR_VERSION "2")

set(BINDING_API_MICRO_VERSION "4")

set(BINDING_API_VERSION "${BINDING_API_MAJOR_VERSION}.${BINDING_API_MINOR_VERSION}.${BINDING_API_MICRO_VERSION}")

option(ENABLE_MAEMO5 "Enable Maemo5 support")

set(LIB_SUFFIX "" CACHE STRING "Define suffix of directory name (32/64)" )

set(LIB_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/lib${LIB_SUFFIX}" CACHE PATH "The subdirectory relative to the install prefix where libraries will be installed (default is /lib${LIB_SUFFIX})" FORCE)

if (NOT CMAKE_BUILD_TYPE)

    set(CMAKE_BUILD_TYPE Release)

endif (NOT CMAKE_BUILD_TYPE)

include(${QT_USE_FILE})

if (${QTVERSION} VERSION_LESS 4.5.0)

    message(FATAL_ERROR "You need Qt4.5, found ${QTVERSION}.")

endif (${QTVERSION} VERSION_LESS 4.5.0)

set(BINDING_VERSION ${BINDING_API_VERSION}.${QT_VERSION_MAJOR}.${QT_VERSION_MINOR})

find_program(GENERATOR generatorrunner REQUIRED)

if (NOT GENERATOR)

    message(FATAL_ERROR "You need to specify GENERATOR variable (-DGENERATOR=value)")

endif (NOT GENERATOR)

# uninstall target

configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake_uninstall.cmake"

               "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"

               IMMEDIATE @ONLY)

add_custom_target(uninstall "${CMAKE_COMMAND}"

                  -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")

add_custom_target(doc

                  DEPENDS docqtcore docqtgui docqtnetwork docqtopengl docqtsql docqtsvg docqtwebkit docqtxml)

# "make dist", in fact "make package_source"

#set(CPACK_SOURCE_PACKAGE_FILE_NAME "pyside-${BINDING_API_VERSION}")

#set(CPACK_SOURCE_GENERATOR TGZ)

#set(CPACK_SOURCE_IGNORE_FILES "~$" ".svn" "debian/" "build/" ".swp$" "*.kdev4" ".git" ".kdev4")

#include(CPack)

set(ARCHIVE_NAME ${CMAKE_PROJECT_NAME}-qt${QT_VERSION_MAJOR}.${QT_VERSION_MINOR}+${BINDING_API_VERSION})

add_custom_target(dist

    COMMAND git archive --prefix=${ARCHIVE_NAME}/ HEAD

        | bzip2 > ${CMAKE_BINARY_DIR}/${ARCHIVE_NAME}.tar.bz2

        WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})

execute_process(

    COMMAND ${PYTHON_EXECUTABLE} -c "from distutils import sysconfig; \\

        print (sysconfig.get_python_lib(1,0,prefix='${CMAKE_INSTALL_PREFIX}'))"

    OUTPUT_VARIABLE SITE_PACKAGE

    OUTPUT_STRIP_TRAILING_WHITESPACE)

if (NOT SITE_PACKAGE)

    message(FATAL_ERROR "Could not detect Python module installation directory.")

endif (NOT SITE_PACKAGE)

set(GENERATOR_EXTRA_FLAGS --generatorSet=boostpython --disable-named-arg)

if (DOC_ONLY)

    set(DOC_ONLY --documentation-only)

endif (DOC_ONLY)

enable_testing()

set(TEST_INSTALL_DIR "${CMAKE_CURRENT_BINARY_DIR}/${BINDING_NAME}")

# project directories

add_subdirectory(data)

add_subdirectory(base)

add_subdirectory(${BINDING_NAME})

add_subdirectory(doc)

add_subdirectory(tests)